Электротехника: мая 2025

Тепловизионные камеры или, по другому, тепловизоры бывают полезными во многих областях т.к. позволяют визуализировать тепловое инфракрасное излучение недоступное человеческому глазу и т.о. как бы увидеть распределение температуры на какой либо поверхности какого либо тела, рассматриваемого в тепловизор. Однако такие камеры, как правило, очень не дешёвые но недорогими бывают модули на основе которых можно сделать тепловизор. Рассмотрим модуль тепловой инфракрасной матрицы AMG8833 это, на момент написания данной статьи, самый дешевый модуль тепловизора. Его матрица состоит из 8 на 8 тепловых датчиков. Т.е. всего 64 штуки. Это не очень много и разрешение данной матрицы не очень велико. Однако же всё таки некоторое подобие изображения можно получить используя данный модуль. Данный модуль можно подключить по I2C к Arduino, ESP32 и другим подобным. Я выбрал ESP32 чтобы можно было использовать смартфон как дисплей. Проще всего написать скетчь будет используя библиотеку. Заходим в менеджер библиотек среды Ардуино и вписываем AMG. Нажимаем кнопку "установка"

а в следующем окне "Install all"

После окончания установки можно открыть пример

с получением данных пикселей матрицы

В данном примере мы видим инициализацию,

запуск,

получение пикселей в матрицу

и вывод данных в последовательный порт.

Если откомпилировать и загрузить скетч

то можно увидеть эти данные в мониторе последовательного порта среды Ардуино.

Чтобы было удобнее пользоваться модулем как тепловизором

можно сделать вывод изображение на экран смартфона в привычном для тепловизоров виде.

Для этого я написал специальный скетч на основе рассмотренного в одном

из предыдущих видео и рассмотренного только что примера.

В начале подключаются заголовочные файлы библиотек,

задается идентификатор и пароль,

настройки айпи адреса. Далее есть код HTML страницы которая будет отображаться на экране смартфона

На этой странице есть canvas для изображения из камеры,

поле для вывода максимальной и минимальной температуры,

кнопка смены кадра или кнопка "сдлеать снимок",

меню для выбора диапазона температур чтобы видеть отличия в цветах на разных разницах температур

В скрипте есть прием данных в формате json

а также отрисовка разноцветных квадратиков в цикле.

В функции инициализации есть инициализация модуля и WIFI точки доступа

а также выдача клиенту HTML страницы и данных в формате json и в конце запуск сервера.

В основном цикле сбор данных с модуля и вывод на uart на всякий случай.

Полный код можно скопировать здесь:

  
#include <Wire.h>
#include <Adafruit_AMG88xx.h>

#include <ESPAsyncWebServer.h>

#ifdef ESP32
  #include <WiFi.h>
  #include <AsyncTCP.h>
#else
  #include <ESP8266WiFi.h>
  #include <ESPAsyncTCP.h>
#endif

Adafruit_AMG88xx amg;

float pixels[AMG88xx_PIXEL_ARRAY_SIZE];

const char* ssid     = "id";
const char *password = "987654321"; // пароль обязательно должен быть длиннее 8ми символов


// Настройки IP адреса 
IPAddress local_IP(192,168,4,22);
IPAddress gateway(192,168,4,9);
IPAddress subnet(255,255,255,0);

// Создаем объект AsyncWebServer на порту 80
AsyncWebServer server(80);
const char index_html[] PROGMEM = R"rawliteral(
<!DOCTYPE HTML><html>
<head>
<meta charset="Windows-1251">
<meta name="viewport" content="user-scalable=no, width=device-width, initial-scale=1.0" /><meta name=\"apple-mobile-web-app-capable\" content=\"yes\" />\
<style>
body{overflow:hidden;width:100%;}
.stk{transform: rotate(-90deg);} /*минус-чтобы начало было внизу*/
.stk::-webkit-slider-thumb{padding:20px;}
.stk::-moz-range-thumb{padding:20px;} /*for Firefox*/
.body{padding:45px;display:flex;flex-direction:row;align-items:center;}
</style>
</head>
<body>
<canvas id="canvas" width="120" height="120"></canvas>
<br>
<span id="data_temp"></span>
<br>
<button id="get_map">get_termal_map</button> range
<select id="sel_range" onchange="selRange()">
  <option value="1">1</option>
  <option value="3">3</option>
  <option value="6">6</option>
  <option value="9">9</option>
  <option value="12">12</option>
</select>
<br>
<script>
var SQ_SIZE = 15; // высота, ширина одного квадрата изображения
var SQ_NUMBER = 64; // колличество кважратов в изображении
var AREA_SIZE = 120-15;
var x = 0;
var y = 0;

var canvas = document.getElementById("canvas");
var ctx = canvas.getContext("2d");

var k_temp = 1;
function selRange()
{
 k_temp = parseInt(document.getElementById("sel_range").value);
}

//document.getElementById("sel_range").addEventListener('click',function (){
//});

var get_map = document.getElementById('get_map');
get_map.addEventListener('click',function (){
  fetch('/update')
      .then(function(response){return response.json();})
      .then(function(result){
        x=0;
        y=AREA_SIZE;

        //get_map.innerHTML = result.termal_map;//.length;
        var max_temp = 0;
        var min_temp = 255;
        for(i=0; i<SQ_NUMBER; i++)
        {
          if(result.termal_map[i] < min_temp) min_temp = result.termal_map[i];
          if(result.termal_map[i] > max_temp) max_temp = result.termal_map[i];
        }

        document.getElementById('data_temp').innerHTML = "max temp="+max_temp+" min temp="+min_temp;

        //var d_temp = max_temp - min_temp;
        //var k_temp = 255/d_temp;
        //var k_temp = 3;
        
        //for(i=1; i<=result.termal_map.length; i++)
        for(i=1; i<=SQ_NUMBER; i++)
        {
          ctx.fillStyle = "rgb("+parseInt((result.termal_map[i-1] - min_temp)*k_temp)+" 0 "+parseInt((255-(result.termal_map[i-1] - min_temp))*k_temp)+")";
          ctx.fillRect(x, y, SQ_SIZE, SQ_SIZE);
          
          x+=SQ_SIZE;
          if( i%8 == 0 ) 
          {
            x=0;
            y-=SQ_SIZE;
          }
        }
        
      });
});
</script>
</body>
</html>
)rawliteral";

void setup() 
{
    Serial.begin(9600);
    Serial.println(F("AMG88xx pixels"));

    bool status;
    
    // default settings
    status = amg.begin();
    if (!status) 
    {
        Serial.println("Could not find a valid AMG88xx sensor, check wiring!");
        while (1);
    }
    Serial.println("-- Pixels Test --");
    Serial.println();
    delay(100); // let sensor boot up

    // для точки доступа
    WiFi.softAPConfig(local_IP, gateway, subnet);
    WiFi.softAP(ssid, password);
    //WiFi.softAP(ssid);
    delay(100);
    IPAddress IP = WiFi.softAPIP();
    Serial.print("AP IP address: ");
    Serial.println(IP);

    // Маршрут для корневой / веб-страницы
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request)
  {
    request->send(200, "text/html", index_html);
  });
  server.on("/update", HTTP_GET, [] (AsyncWebServerRequest *request) 
  {
  String response = ""; // ответ клиенту
  
    response += "{\"termal_map\":";
    response += "[";
    for(int i=1; i<AMG88xx_PIXEL_ARRAY_SIZE; i++)
    {
      response += String(pixels[i-1]);
      response += ",";
    }
    response += String(pixels[AMG88xx_PIXEL_ARRAY_SIZE-1]);//чтобы не было запятой в конце
    response += "]}";
    request->send(200, "application/json", response);
  });
  // Запустить сервер
  server.begin();
}


void loop() 
{ 
    //read all the pixels
    amg.readPixels(pixels);

    Serial.print("[");
    for(int i=1; i<=AMG88xx_PIXEL_ARRAY_SIZE; i++)
    {
      Serial.print(pixels[i-1]);
      Serial.print(", ");
      if( i%8 == 0 ) Serial.println();
    }
    Serial.println("]");
    Serial.println();

    //delay a second
    delay(1000);
}

Результат можно посмотреть на видео:

Адрес биткоин кошелька для поддержки блога - bc1qlhrmmkh77x2lzhqe4lt9qwkglswj64tsqt2l5g

Электротехника

суббота, 24 мая 2025 г.

Тепловизор на AMG88xx модуле тепловой инфракрасной матрице

суббота, 24 мая 2025 г.

Тепловизор на AMG88xx модуле тепловой инфракрасной матрице

суббота, 24 мая 2025 г.